Testbenches et Simulations

Name: Testbenches et Simulations
Author: Dangremont Jayson

Par Dangremont JaysonÀ propos de l’auteur

Écrire un testbench VHDL auto-vérifiant : DUT, horloge, reset, stimuli, assertions et vérification avant synthèse.

Un testbench pilote les entrées du DUT (device under test) et compare les sorties au résultat attendu. Les assertions donnent un verdict ; les chronogrammes aident à comprendre un échec.

Construire le scénario

Le testbench présenté ici est un environnement autonome dont l'entité n'a pas de ports :

entity tb_mux4to1 is
  -- Pas de port !

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.NUMERIC_STD.ALL;
 
entity tb_mux4to1 is
end entity tb_mux4to1;
 
architecture tb of tb_mux4to1 is
 
  -- Constantes de simulation
  constant c_CLK_PERIOD : time := 10 ns;  -- 100 MHz
 
  -- Signaux pour connecter au DUT
  signal w_d0, w_d1, w_d2, w_d3 : std_logic := '0';
  signal w_sel : std_logic_vector(1 downto 0) := "00";
  signal w_y   : std_logic;
 
begin
 
  -- Instanciation du DUT
  DUT : entity work.mux4to1
    port map (
      i_d0  => w_d0,
      i_d1  => w_d1,
      i_d2  => w_d2,
      i_d3  => w_d3,
      i_sel => w_sel,
      o_y   => w_y
    );
 
  -- Process de stimuli
  p_stimuli : process
  begin
    -- Test 1 : sélection d0
    w_d0 <= '1'; w_d1 <= '0'; w_d2 <= '0'; w_d3 <= '0';
    w_sel <= "00";
    wait for 20 ns;
    assert w_y = '1' report "ECHEC: sel=00 devrait sortir d0=1" severity error;
 
    -- Test 2 : sélection d1
    w_sel <= "01";
    wait for 20 ns;
    assert w_y = '0' report "ECHEC: sel=01 devrait sortir d1=0" severity error;
 
    -- Test 3 : sélection d3
    w_d3 <= '1';
    w_sel <= "11";
    wait for 20 ns;
    assert w_y = '1' report "ECHEC: sel=11 devrait sortir d3=1" severity error;
 
    report "Tous les tests passés !" severity note;
    wait;  -- arrêt de la simulation
  end process p_stimuli;
 
end architecture tb;

-- Process de génération d'horloge
p_clk : process
begin
  i_clk <= '0';
  wait for c_CLK_PERIOD / 2;
  i_clk <= '1';
  wait for c_CLK_PERIOD / 2;
end process p_clk;
 
-- Alternative concurrente
i_clk <= not i_clk after c_CLK_PERIOD / 2;

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.NUMERIC_STD.ALL;
use std.env.all;
 
entity tb_counter is
end entity tb_counter;
 
architecture tb of tb_counter is
 
  constant c_CLK_PERIOD : time := 10 ns;
 
  signal i_clk : std_logic := '0';
  signal i_rst : std_logic := '1';
  signal o_cnt : std_logic_vector(3 downto 0);
 
begin
 
  -- Génération horloge
  i_clk <= not i_clk after c_CLK_PERIOD / 2;
 
  -- DUT
  DUT : entity work.counter_4bit
    port map (
      i_clk => i_clk,
      i_rst => i_rst,
      o_cnt => o_cnt
    );
 
  -- Stimuli
  p_test : process
  begin
    -- Reset actif pendant 3 cycles
    i_rst <= '1';
    wait for 3 * c_CLK_PERIOD;
    assert unsigned(o_cnt) = 0 report "Reset raté" severity error;
 
    -- Démarrage comptage
    i_rst <= '0';
    wait for 5 * c_CLK_PERIOD;
    assert unsigned(o_cnt) = 5 report "Comptage incorrect" severity error;
 
    -- Attendre l'overflow (16 cycles total = 0)
    wait for 11 * c_CLK_PERIOD;
    assert unsigned(o_cnt) = 0 report "Overflow incorrect" severity error;
 
    report "Testbench terminé avec succès" severity note;
    finish;
  end process p_test;
 
end architecture tb;

Instruction	Utilisation
`wait for 10 ns;`	Attendre une durée fixe
`wait until rising_edge(i_clk);`	Attendre un front d'horloge
`wait until i_valid = '1';`	Attendre une condition
`wait;`	Suspendre définitivement le process courant
`assert condition report "msg" severity level;`	Vérification

-- Avant le begin de l'architecture tb
procedure check_slv(
  constant i_name     : in string;
  constant i_observed : in std_logic_vector;
  constant i_expected : in std_logic_vector
) is
begin
  assert i_observed = i_expected
    report i_name
      & " attendu=0x" & to_hstring(i_expected)
      & " obtenu=0x" & to_hstring(i_observed)
    severity error;
end procedure check_slv;

Niveau	Message
`note`	Information
`warning`	Avertissement
`error`	Échec de vérification
`failure`	Échec grave ; arrêt usuel au seuil par défaut

Testbenches et Simulations

Construire le scénario

Donner un verdict utile

Terminer la simulation